Как-то при написании монитора клавиатуры (в народе - "клавирного шпиона") столкнулся с проблемой передачи данных между динамически подключаемыми библиотеками (DLL). Надо было где-то хранить хэндл окна и сравнивать его с текущим. Проблема же заключалась в том, что библиотеки при загрузке отображаются в адресное пространство каждого вызвавшего их процесса, т.е. при каждом вызове библиотеки она загружается всякий раз в новое адресное пространство. Вот и получается, что в случае, если два различных процесса загрузят одну и ту же DLL, манипулирование с любыми данными внутри одной DLL никак не скажется на этих же данных внутри другого экземпляра той же самой DLL. Мне же требовалось, чтобы к хэндлу окна был доступ из любого процесса, загрузившего эту DLL. Одним из способов решения поставленной задачи оказалось использование объекта файлового отображения (FileMapping). Правда, поставленную задачу я решил несколько другим, более элегантным способом, возможно о нем расскажу в другой раз. Однако для "общего случая" обмена данными между процессами использование FileMapping подходит лучше всего. В этой статье использование FileMapping для DLL рассматриваться не будет, т.к. понять "как все работает" будет проще на примере небольшого простенького приложения.

Как все работает

Под "памятью" в Windows подразумевается не только физическая память (ОЗУ), но также память, резервируемая операционный системой на жестком диске. Этот вид памяти называется "виртуальной памятью" и образует так называемый страничный свап-файл или "файл подкачки". По мере необходимости операционная среда обращается к этому файлу, чтобы поместить в него пока ненужные системе данные или наоборот считать в ОЗУ уже потребовавшиеся данные (как все это система делает надо спросить у Билла Гейтса). Но, не вдаваясь в подробности реализации страничных файлов подкачки, мы можем использовать эту особенность Windows в своих интересах. Например, поместить каким-то способом в свап-файл нужные уже НЕ СИСТЕМЕ, А НАМ данные, чтобы затем можно было бы обратиться к этому файлу из любого другого процесса и считать или изменить нужные данные. К счастью, WinAPI предоставляет способ работы со свап-файлом посредством так называемого объекта файлового отображения.

FileMapping - объект файлового отображения

CreateFileMapping или создание объекта файлового отображения.

Если вспомнить написанное выше, то страничный файл операционной системы используется как расширение памяти. Под расширением понимается процесс подкачки (swap) ОЗУ, вызывающийся системой по мере необходимости. Таким образом, создав объект файлового отображения, связанный со страничным свап-файлом, мы получим в качестве результата выделение глобально доступной памяти. Так как эта память является общедоступной, то любой другой процесс, создавший экземпляр объекта файлового отображения, будет иметь доступ к этим данным.

Function CreateFileMapping(hFile: THandle;                             
lpFileMappingAttributes: PSecurityAttributes;                             
flProtect, dwMaximumSizeHigh, dwMaximumSizeLow: DWORD;                             
lpName: PChar): THandle;  

MapViewOfFile или подключение объекта файлового отображения к адресному пространству.

Будучи созданным при помощи функции CreateFileMapping, объект файлового отображения должен отображать связанный с ним файл (в нашем случае страничный свап-файл операционной системы) в адресное пространство процессов. В результате выполнения MapViewOfFile мы получим начальный адрес нужных нам данных.

Function MapViewOfFile(hFileMappingObject: THandle;                        
dwDesiredAccess: DWORD;                        
dwFileOffsetHigh, dwFileOffsetLow,                        
dwNumberOfBytesToMap: DWORD): Pointer;  

UnMapViewOfFile или прекращение отображения данных.

Для отключения от текущего процесса объекта файлового отображения используется функция UnMapViewOfFile.

Function UnMapViewOfFile(lpBaseAddress: Pointer): Boolean;  

CloseHandle или закрытие объекта файлового отображения.

Для уничтожения объекта файлового отображения и освобождения памяти используется функция CloseHandle.

Function CloseHandle(hFileMapObj:THandle):Boolean;  

Для правильного завершения работы с объектом файлового отображения вначале следует применить функцию UnMapViewOfFile, а затем CloseHandle.

Прототипы функций (кроме CloseHandle) и необходимые константы определены в файле Windows.pas. Этот файл находится в созданной при установке Delphi директории \Borland\Delphi_X\Source\Rtl\Win

Однако "чистая теория" не дает полного представления о том, как все может выглядеть на практике. Поэтому рассмотрим небольшой практический пример.

Небольшой практический пример

Поместите на форму TEdit, 2 экземпляра TBitBtn, TTimer и 3 экземпляра TLabel.
В строку ввода будем вводить свои данные в виде текста. Далее, нажав на кнопку OK, передадим данные в объект файлового отображения. Считывать данные из этого объекта будем на событие OnTimer. Описатель объекта файлового отображения поместим в глобальную переменную hFileMapObj типа THandle, указатель на начальный адрес данных объекта поместим в глобальную переменную lpBaseAddress типа PChar (хотя в результате выполнения функции MapViewOfFile возвращается переменная типа Pointer, компилятор на указание типа PChar вместо Pointer не "ругается", т.к. по большому счету PChar - это тоже указатель).

unit Main;
 
interface
 
uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs, StdCtrls, Buttons, ExtCtrls;
 
type
     TForm1 = class(TForm)
     edVariable: TEdit;
     lbEnterValues: TLabel;
     bbOK: TBitBtn;
     bbExit: TBitBtn;
     lbShowValue: TLabel;
     lbVariable: TLabel;
     Timer1: TTimer;
     procedure FormCreate(Sender: TObject);
     procedure bbExitClick(Sender: TObject);
     procedure FormClose(Sender: TObject; var Action: TCloseAction);
     procedure bbOKClick(Sender: TObject);
     procedure Timer1Timer(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;
 
var
     Form1: TForm1;
//глобальные переменные
     hFileMapObj:THandle;//описатель FaleMapping
     lpBaseAddress:PChar;//"указатель" (см. выше) на начальный адрес данных
implementation
 
{$R *.DFM}
 
procedure TForm1.FormCreate(Sender: TObject);
begin
//создадим FileMapping с именем MySharedValue
//и передадим его хэндл в глобальную переменную hFileMapObj
    hFileMapObj:=CreateFileMapping(MAXDWORD,Nil,PAGE_READWRITE,0,4,'MySharedValue');
     If (hFileMapObj=0) Then
//ошибочка вышла
         ShowMessage('Не могу создать FileMapping!')
     Else
//подключим FileMapping к адресному пространству
//и получим начальный адрес данных
         lpBaseAddress:=MapViewOfFile(hFileMapObj,FILE_MAP_WRITE,0,0,0);
     If lpBaseAddress=Nil Then
//ошибочка вышла
         ShowMessage('Не могу подключить FileMapping!');
end;
 
procedure TForm1.bbExitClick(Sender: TObject);
begin
//закроем форму
     Close;
end;
 
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
//кое-что надо сделать при закрытии формы:
//отключим FileMapping от адресного пространства
     UnMapViewOfFile(lpBaseAddress);
//освободим объект FileMapping
     CloseHandle(hFileMapObj);
//теперь форму можно закрыть
     Action:=caFree;
end;
 
procedure TForm1.bbOKClick(Sender: TObject);
begin
//поместим в адресное пространство свои данные
//переменная типа PChar имеет в конце завершающий #0, значит при считывании данных
//система сама сможет определить, где находится конец нужных данных
    StrPCopy(lpBaseAddress,edVariable.Text);
end;
 
procedure TForm1.Timer1Timer(Sender: TObject);
begin
//считаем нужные данные, обратившись по начальному адресу
//данных адресного пространства FileMapping
     lbVariable.Caption:=PChar(lpBaseAddress);
end;
 
end.

Постскриптум

Статья нисколько не претендует на академичность изложения, поскольку сведения были почерпнуты из совершенно различных источников, которые во многом друг другу противоречат и в определениях и в понятиях. Однако, как говорится, "все работает"...

Файлы проекта лежат здесь: FileMappingEx.zip (2.5K)
Запустите несколько экземпляров приложения и посмотрите, как все работает.